project('cmsis-driver-bare', 'c',
  version: '1.0.0',
  license: 'MIT',
  meson_version: '>=0.60.0')

subdir('cross/armv7m')

cmsis_core_dep = subproject('cmsis').get_variable('cmsis_core_dep')
cmsis_driver_dep = subproject('cmsis').get_variable('cmsis_driver_dep')
cmsis_rtos_dep = subproject('cmsis').get_variable('cmsis_rtos_dep')
cmsis_dfp_dep = subproject('cmsis-dfp-stm32f4').get_variable('cmsis_dfp_stm32f4_dep')
freertos_dep = subproject('cmsis-freertos').get_variable('cmsis_freertos_dep')
cmsis_dv_dep = subproject('cmsis-driver-validation').get_variable('cmsis_dv_dep')
internal_inc = include_directories('inc')

subdir('lib')
if get_option('enable_demos')
  subdir('demo')
endif
if get_option('enable_tests')
  subdir('test')
endif

if get_option('enable_demos') and gdb.found() and ocd.found() and objcopy.found()
  run_target('flash', command: [flash_cmd, demo_gpio])
  run_target('gdb', command: [gdb_cmd, demo_gpio])
  if ddd.found()
    run_target('ddd', command: [ddd_cmd, demo_gpio])
  endif
endif

if get_option('enable_tests') and gdb.found() and ocd.found() and objcopy.found()
  run_target('flash-test', command: [flash_cmd, test_cmsis_validate])
  run_target('gdb-test', command: [gdb_cmd, test_cmsis_validate])
  if ddd.found()
    run_target('ddd-test', command: [ddd_cmd, test_cmsis_validate])
  endif
endif