begriffs open source - cmsis-freertos/blob - Source/portable/GCC/RISC-V/portASM.S

   1 /*
   2  * FreeRTOS Kernel V10.6.2
   3  * Copyright (C) 2021 Amazon.com, Inc. or its affiliates.  All Rights Reserved.
   4  *
   5  * SPDX-License-Identifier: MIT
   6  *
   7  * Permission is hereby granted, free of charge, to any person obtaining a copy of
   8  * this software and associated documentation files (the "Software"), to deal in
   9  * the Software without restriction, including without limitation the rights to
  10  * use, copy, modify, merge, publish, distribute, sublicense, and/or sell copies of
  11  * the Software, and to permit persons to whom the Software is furnished to do so,
  12  * subject to the following conditions:
  13  *
  14  * The above copyright notice and this permission notice shall be included in all
  15  * copies or substantial portions of the Software.
  16  *
  17  * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  18  * IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY, FITNESS
  19  * FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE AUTHORS OR
  20  * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER
  21  * IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN
  22  * CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
  23  *
  24  * https://www.FreeRTOS.org
  25  * https://github.com/FreeRTOS
  26  *
  27  */
  28
  29 /*
  30  * The FreeRTOS kernel's RISC-V port is split between the the code that is
  31  * common across all currently supported RISC-V chips (implementations of the
  32  * RISC-V ISA), and code which tailors the port to a specific RISC-V chip:
  33  *
  34  * + The code that is common to all RISC-V chips is implemented in
  35  *   FreeRTOS\Source\portable\GCC\RISC-V-RV32\portASM.S.  There is only one
  36  *   portASM.S file because the same file is used no matter which RISC-V chip is
  37  *   in use.
  38  *
  39  * + The code that tailors the kernel's RISC-V port to a specific RISC-V
  40  *   chip is implemented in freertos_risc_v_chip_specific_extensions.h.  There
  41  *   is one freertos_risc_v_chip_specific_extensions.h that can be used with any
  42  *   RISC-V chip that both includes a standard CLINT and does not add to the
  43  *   base set of RISC-V registers.  There are additional
  44  *   freertos_risc_v_chip_specific_extensions.h files for RISC-V implementations
  45  *   that do not include a standard CLINT or do add to the base set of RISC-V
  46  *   registers.
  47  *
  48  * CARE MUST BE TAKEN TO INCLDUE THE CORRECT
  49  * freertos_risc_v_chip_specific_extensions.h HEADER FILE FOR THE CHIP
  50  * IN USE.  To include the correct freertos_risc_v_chip_specific_extensions.h
  51  * header file ensure the path to the correct header file is in the assembler's
  52  * include path.
  53  *
  54  * This freertos_risc_v_chip_specific_extensions.h is for use on RISC-V chips
  55  * that include a standard CLINT and do not add to the base set of RISC-V
  56  * registers.
  57  *
  58  */
  59
  60 #include "portContext.h"
  61
  62 /* Check the freertos_risc_v_chip_specific_extensions.h and/or command line
  63 definitions. */
  64 #if defined( portasmHAS_CLINT ) && defined( portasmHAS_MTIME )
  65     #error The portasmHAS_CLINT constant has been deprecated.  Please replace it with portasmHAS_MTIME.  portasmHAS_CLINT and portasmHAS_MTIME cannot both be defined at once.  See https://www.FreeRTOS.org/Using-FreeRTOS-on-RISC-V.html
  66 #endif
  67
  68 #ifdef portasmHAS_CLINT
  69     #warning The portasmHAS_CLINT constant has been deprecated.  Please replace it with portasmHAS_MTIME and portasmHAS_SIFIVE_CLINT.  For now portasmHAS_MTIME and portasmHAS_SIFIVE_CLINT are derived from portasmHAS_CLINT.  See https://www.FreeRTOS.org/Using-FreeRTOS-on-RISC-V.html
  70     #define portasmHAS_MTIME portasmHAS_CLINT
  71     #define portasmHAS_SIFIVE_CLINT portasmHAS_CLINT
  72 #endif
  73
  74 #ifndef portasmHAS_MTIME
  75     #error freertos_risc_v_chip_specific_extensions.h must define portasmHAS_MTIME to either 1 (MTIME clock present) or 0 (MTIME clock not present).  See https://www.FreeRTOS.org/Using-FreeRTOS-on-RISC-V.html
  76 #endif
  77
  78 #ifndef portasmHAS_SIFIVE_CLINT
  79     #define portasmHAS_SIFIVE_CLINT 0
  80 #endif
  81
  82 .global xPortStartFirstTask
  83 .global pxPortInitialiseStack
  84 .global freertos_risc_v_trap_handler
  85 .global freertos_risc_v_exception_handler
  86 .global freertos_risc_v_interrupt_handler
  87 .global freertos_risc_v_mtimer_interrupt_handler
  88
  89 .extern vTaskSwitchContext
  90 .extern xTaskIncrementTick
  91 .extern pullMachineTimerCompareRegister
  92 .extern pullNextTime
  93 .extern uxTimerIncrementsForOneTick /* size_t type so 32-bit on 32-bit core and 64-bits on 64-bit core. */
  94 .extern xTaskReturnAddress
  95
  96 .weak freertos_risc_v_application_exception_handler
  97 .weak freertos_risc_v_application_interrupt_handler
  98 /*-----------------------------------------------------------*/
  99
 100 .macro portUPDATE_MTIMER_COMPARE_REGISTER
 101     load_x a0, pullMachineTimerCompareRegister  /* Load address of compare register into a0. */
 102     load_x a1, pullNextTime                     /* Load the address of ullNextTime into a1. */
 103
 104     #if( __riscv_xlen == 32 )
 105
 106         /* Update the 64-bit mtimer compare match value in two 32-bit writes. */
 107         li a4, -1
 108         lw a2, 0(a1)                /* Load the low word of ullNextTime into a2. */
 109         lw a3, 4(a1)                /* Load the high word of ullNextTime into a3. */
 110         sw a4, 0(a0)                /* Low word no smaller than old value to start with - will be overwritten below. */
 111         sw a3, 4(a0)                /* Store high word of ullNextTime into compare register.  No smaller than new value. */
 112         sw a2, 0(a0)                /* Store low word of ullNextTime into compare register. */
 113         lw t0, uxTimerIncrementsForOneTick  /* Load the value of ullTimerIncrementForOneTick into t0 (could this be optimized by storing in an array next to pullNextTime?). */
 114         add a4, t0, a2              /* Add the low word of ullNextTime to the timer increments for one tick (assumes timer increment for one tick fits in 32-bits). */
 115         sltu t1, a4, a2             /* See if the sum of low words overflowed (what about the zero case?). */
 116         add t2, a3, t1              /* Add overflow to high word of ullNextTime. */
 117         sw a4, 0(a1)                /* Store new low word of ullNextTime. */
 118         sw t2, 4(a1)                /* Store new high word of ullNextTime. */
 119
 120     #endif /* __riscv_xlen == 32 */
 121
 122     #if( __riscv_xlen == 64 )
 123
 124         /* Update the 64-bit mtimer compare match value. */
 125         ld t2, 0(a1)                /* Load ullNextTime into t2. */
 126         sd t2, 0(a0)                /* Store ullNextTime into compare register. */
 127         ld t0, uxTimerIncrementsForOneTick  /* Load the value of ullTimerIncrementForOneTick into t0 (could this be optimized by storing in an array next to pullNextTime?). */
 128         add t4, t0, t2              /* Add ullNextTime to the timer increments for one tick. */
 129         sd t4, 0(a1)                /* Store ullNextTime. */
 130
 131     #endif /* __riscv_xlen == 64 */
 132     .endm
 133 /*-----------------------------------------------------------*/
 134
 135 /*
 136  * Unlike other ports pxPortInitialiseStack() is written in assembly code as it
 137  * needs access to the portasmADDITIONAL_CONTEXT_SIZE constant.  The prototype
 138  * for the function is as per the other ports:
 139  * StackType_t *pxPortInitialiseStack( StackType_t *pxTopOfStack, TaskFunction_t pxCode, void *pvParameters );
 140  *
 141  * As per the standard RISC-V ABI pxTopcOfStack is passed in in a0, pxCode in
 142  * a1, and pvParameters in a2.  The new top of stack is passed out in a0.
 143  *
 144  * RISC-V maps registers to ABI names as follows (X1 to X31 integer registers
 145  * for the 'I' profile, X1 to X15 for the 'E' profile, currently I assumed).
 146  *
 147  * Register      ABI Name    Description                       Saver
 148  * x0            zero        Hard-wired zero                   -
 149  * x1            ra          Return address                    Caller
 150  * x2            sp          Stack pointer                     Callee
 151  * x3            gp          Global pointer                    -
 152  * x4            tp          Thread pointer                    -
 153  * x5-7          t0-2        Temporaries                       Caller
 154  * x8            s0/fp       Saved register/Frame pointer      Callee
 155  * x9            s1          Saved register                    Callee
 156  * x10-11        a0-1        Function Arguments/return values  Caller
 157  * x12-17        a2-7        Function arguments                Caller
 158  * x18-27        s2-11       Saved registers                   Callee
 159  * x28-31        t3-6        Temporaries                       Caller
 160  *
 161  * The RISC-V context is saved t FreeRTOS tasks in the following stack frame,
 162  * where the global and thread pointers are currently assumed to be constant so
 163  * are not saved:
 164  *
 165  * mstatus
 166  * xCriticalNesting
 167  * x31
 168  * x30
 169  * x29
 170  * x28
 171  * x27
 172  * x26
 173  * x25
 174  * x24
 175  * x23
 176  * x22
 177  * x21
 178  * x20
 179  * x19
 180  * x18
 181  * x17
 182  * x16
 183  * x15
 184  * x14
 185  * x13
 186  * x12
 187  * x11
 188  * pvParameters
 189  * x9
 190  * x8
 191  * x7
 192  * x6
 193  * x5
 194  * portTASK_RETURN_ADDRESS
 195  * [chip specific registers go here]
 196  * pxCode
 197  */
 198 pxPortInitialiseStack:
 199     csrr t0, mstatus                    /* Obtain current mstatus value. */
 200     andi t0, t0, ~0x8                   /* Ensure interrupts are disabled when the stack is restored within an ISR.  Required when a task is created after the schedulre has been started, otherwise interrupts would be disabled anyway. */
 201     addi t1, x0, 0x188                  /* Generate the value 0x1880, which are the MPIE and MPP bits to set in mstatus. */
 202     slli t1, t1, 4
 203     or t0, t0, t1                       /* Set MPIE and MPP bits in mstatus value. */
 204
 205     addi a0, a0, -portWORD_SIZE
 206     store_x t0, 0(a0)                   /* mstatus onto the stack. */
 207     addi a0, a0, -portWORD_SIZE         /* Space for critical nesting count. */
 208     store_x x0, 0(a0)                   /* Critical nesting count starts at 0 for every task. */
 209
 210 #ifdef __riscv_32e
 211     addi a0, a0, -(6 * portWORD_SIZE)   /* Space for registers x10-x15. */
 212 #else
 213     addi a0, a0, -(22 * portWORD_SIZE)  /* Space for registers x10-x31. */
 214 #endif
 215     store_x a2, 0(a0)                   /* Task parameters (pvParameters parameter) goes into register X10/a0 on the stack. */
 216     addi a0, a0, -(6 * portWORD_SIZE)   /* Space for registers x5-x9 + taskReturnAddress. */
 217     load_x t0, xTaskReturnAddress
 218     store_x t0, 0(a0)                   /* Return address onto the stack. */
 219     addi t0, x0, portasmADDITIONAL_CONTEXT_SIZE /* The number of chip specific additional registers. */
 220 chip_specific_stack_frame:              /* First add any chip specific registers to the stack frame being created. */
 221     beq t0, x0, 1f                      /* No more chip specific registers to save. */
 222     addi a0, a0, -portWORD_SIZE         /* Make space for chip specific register. */
 223     store_x x0, 0(a0)                   /* Give the chip specific register an initial value of zero. */
 224     addi t0, t0, -1                     /* Decrement the count of chip specific registers remaining. */
 225     j chip_specific_stack_frame         /* Until no more chip specific registers. */
 226 1:
 227     addi a0, a0, -portWORD_SIZE
 228     store_x a1, 0(a0)                   /* mret value (pxCode parameter) onto the stack. */
 229     ret
 230 /*-----------------------------------------------------------*/
 231
 232 xPortStartFirstTask:
 233     load_x  sp, pxCurrentTCB            /* Load pxCurrentTCB. */
 234     load_x  sp, 0( sp )                 /* Read sp from first TCB member. */
 235
 236     load_x  x1, 0( sp ) /* Note for starting the scheduler the exception return address is used as the function return address. */
 237
 238     portasmRESTORE_ADDITIONAL_REGISTERS /* Defined in freertos_risc_v_chip_specific_extensions.h to restore any registers unique to the RISC-V implementation. */
 239
 240     load_x  x7, 4 * portWORD_SIZE( sp )     /* t2 */
 241     load_x  x8, 5 * portWORD_SIZE( sp )     /* s0/fp */
 242     load_x  x9, 6 * portWORD_SIZE( sp )     /* s1 */
 243     load_x  x10, 7 * portWORD_SIZE( sp )    /* a0 */
 244     load_x  x11, 8 * portWORD_SIZE( sp )    /* a1 */
 245     load_x  x12, 9 * portWORD_SIZE( sp )    /* a2 */
 246     load_x  x13, 10 * portWORD_SIZE( sp )   /* a3 */
 247     load_x  x14, 11 * portWORD_SIZE( sp )   /* a4 */
 248     load_x  x15, 12 * portWORD_SIZE( sp )   /* a5 */
 249 #ifndef __riscv_32e
 250     load_x  x16, 13 * portWORD_SIZE( sp )   /* a6 */
 251     load_x  x17, 14 * portWORD_SIZE( sp )   /* a7 */
 252     load_x  x18, 15 * portWORD_SIZE( sp )   /* s2 */
 253     load_x  x19, 16 * portWORD_SIZE( sp )   /* s3 */
 254     load_x  x20, 17 * portWORD_SIZE( sp )   /* s4 */
 255     load_x  x21, 18 * portWORD_SIZE( sp )   /* s5 */
 256     load_x  x22, 19 * portWORD_SIZE( sp )   /* s6 */
 257     load_x  x23, 20 * portWORD_SIZE( sp )   /* s7 */
 258     load_x  x24, 21 * portWORD_SIZE( sp )   /* s8 */
 259     load_x  x25, 22 * portWORD_SIZE( sp )   /* s9 */
 260     load_x  x26, 23 * portWORD_SIZE( sp )   /* s10 */
 261     load_x  x27, 24 * portWORD_SIZE( sp )   /* s11 */
 262     load_x  x28, 25 * portWORD_SIZE( sp )   /* t3 */
 263     load_x  x29, 26 * portWORD_SIZE( sp )   /* t4 */
 264     load_x  x30, 27 * portWORD_SIZE( sp )   /* t5 */
 265     load_x  x31, 28 * portWORD_SIZE( sp )   /* t6 */
 266 #endif
 267
 268     load_x  x5, portCRITICAL_NESTING_OFFSET * portWORD_SIZE( sp )    /* Obtain xCriticalNesting value for this task from task's stack. */
 269     load_x  x6, pxCriticalNesting           /* Load the address of xCriticalNesting into x6. */
 270     store_x x5, 0( x6 )                     /* Restore the critical nesting value for this task. */
 271
 272     load_x  x5, portMSTATUS_OFFSET * portWORD_SIZE( sp )    /* Initial mstatus into x5 (t0). */
 273     addi    x5, x5, 0x08                    /* Set MIE bit so the first task starts with interrupts enabled - required as returns with ret not eret. */
 274     csrrw   x0, mstatus, x5                 /* Interrupts enabled from here! */
 275
 276     load_x  x5, 2 * portWORD_SIZE( sp )     /* Initial x5 (t0) value. */
 277     load_x  x6, 3 * portWORD_SIZE( sp )     /* Initial x6 (t1) value. */
 278
 279     addi    sp, sp, portCONTEXT_SIZE
 280     ret
 281 /*-----------------------------------------------------------*/
 282
 283 freertos_risc_v_application_exception_handler:
 284     csrr t0, mcause     /* For viewing in the debugger only. */
 285     csrr t1, mepc       /* For viewing in the debugger only */
 286     csrr t2, mstatus    /* For viewing in the debugger only */
 287     j .
 288 /*-----------------------------------------------------------*/
 289
 290 freertos_risc_v_application_interrupt_handler:
 291     csrr t0, mcause     /* For viewing in the debugger only. */
 292     csrr t1, mepc       /* For viewing in the debugger only */
 293     csrr t2, mstatus    /* For viewing in the debugger only */
 294     j .
 295 /*-----------------------------------------------------------*/
 296
 297 .section .text.freertos_risc_v_exception_handler
 298 freertos_risc_v_exception_handler:
 299     portcontextSAVE_EXCEPTION_CONTEXT
 300     /* a0 now contains mcause. */
 301     li t0, 11                           /* 11 == environment call. */
 302     bne a0, t0, other_exception         /* Not an M environment call, so some other exception. */
 303     call vTaskSwitchContext
 304     portcontextRESTORE_CONTEXT
 305
 306 other_exception:
 307     call freertos_risc_v_application_exception_handler
 308     portcontextRESTORE_CONTEXT
 309 /*-----------------------------------------------------------*/
 310
 311 .section .text.freertos_risc_v_interrupt_handler
 312 freertos_risc_v_interrupt_handler:
 313     portcontextSAVE_INTERRUPT_CONTEXT
 314     call freertos_risc_v_application_interrupt_handler
 315     portcontextRESTORE_CONTEXT
 316 /*-----------------------------------------------------------*/
 317
 318 .section .text.freertos_risc_v_mtimer_interrupt_handler
 319 freertos_risc_v_mtimer_interrupt_handler:
 320     portcontextSAVE_INTERRUPT_CONTEXT
 321     portUPDATE_MTIMER_COMPARE_REGISTER
 322     call xTaskIncrementTick
 323     beqz a0, exit_without_context_switch    /* Don't switch context if incrementing tick didn't unblock a task. */
 324     call vTaskSwitchContext
 325 exit_without_context_switch:
 326     portcontextRESTORE_CONTEXT
 327 /*-----------------------------------------------------------*/
 328
 329 .section .text.freertos_risc_v_trap_handler
 330 .align 8
 331 freertos_risc_v_trap_handler:
 332     portcontextSAVE_CONTEXT_INTERNAL
 333
 334     csrr a0, mcause
 335     csrr a1, mepc
 336
 337     bge a0, x0, synchronous_exception
 338
 339 asynchronous_interrupt:
 340     store_x a1, 0( sp )                 /* Asynchronous interrupt so save unmodified exception return address. */
 341     load_x sp, xISRStackTop             /* Switch to ISR stack. */
 342     j handle_interrupt
 343
 344 synchronous_exception:
 345     addi a1, a1, 4                      /* Synchronous so update exception return address to the instruction after the instruction that generated the exeption. */
 346     store_x a1, 0( sp )                 /* Save updated exception return address. */
 347     load_x sp, xISRStackTop             /* Switch to ISR stack. */
 348     j handle_exception
 349
 350 handle_interrupt:
 351 #if( portasmHAS_MTIME != 0 )
 352
 353     test_if_mtimer:                     /* If there is a CLINT then the mtimer is used to generate the tick interrupt. */
 354         addi t0, x0, 1
 355         slli t0, t0, __riscv_xlen - 1   /* LSB is already set, shift into MSB.  Shift 31 on 32-bit or 63 on 64-bit cores. */
 356         addi t1, t0, 7                  /* 0x8000[]0007 == machine timer interrupt. */
 357         bne a0, t1, application_interrupt_handler
 358
 359         portUPDATE_MTIMER_COMPARE_REGISTER
 360         call xTaskIncrementTick
 361         beqz a0, processed_source       /* Don't switch context if incrementing tick didn't unblock a task. */
 362         call vTaskSwitchContext
 363         j processed_source
 364
 365 #endif /* portasmHAS_MTIME */
 366
 367 application_interrupt_handler:
 368     call freertos_risc_v_application_interrupt_handler
 369     j processed_source
 370
 371 handle_exception:
 372     /* a0 contains mcause. */
 373     li t0, 11                                   /* 11 == environment call. */
 374     bne a0, t0, application_exception_handler   /* Not an M environment call, so some other exception. */
 375     call vTaskSwitchContext
 376     j processed_source
 377
 378 application_exception_handler:
 379     call freertos_risc_v_application_exception_handler
 380     j processed_source                  /* No other exceptions handled yet. */
 381
 382 processed_source:
 383     portcontextRESTORE_CONTEXT
 384 /*-----------------------------------------------------------*/