begriffs open source - cmsis-freertos/blob - Source/portable/IAR/ARM_CA9/portASM.h

   1 ;/*
   2 ;    FreeRTOS V9.0.0 - Copyright (C) 2016 Real Time Engineers Ltd.
   3 ;    All rights reserved
   4 ;
   5 ;
   6 ;    ***************************************************************************
   7 ;     *                                                                       *
   8 ;     *    FreeRTOS tutorial books are available in pdf and paperback.        *
   9 ;     *    Complete, revised, and edited pdf reference manuals are also       *
  10 ;     *    available.                                                         *
  11 ;     *                                                                       *
  12 ;     *    Purchasing FreeRTOS documentation will not only help you, by       *
  13 ;     *    ensuring you get running as quickly as possible and with an        *
  14 ;     *    in-depth knowledge of how to use FreeRTOS, it will also help       *
  15 ;     *    the FreeRTOS project to continue with its mission of providing     *
  16 ;     *    professional grade, cross platform, de facto standard solutions    *
  17 ;     *    for microcontrollers - completely free of charge!                  *
  18 ;     *                                                                       *
  19 ;     *    >>> See http://www.FreeRTOS.org/Documentation for details. <<<     *
  20 ;     *                                                                       *
  21 ;     *    Thank you for using FreeRTOS, and thank you for your support!      *
  22 ;     *                                                                       *
  23 ;    ***************************************************************************
  24 ;
  25 ;
  26 ;    This file is part of the FreeRTOS distribution.
  27 ;
  28 ;    FreeRTOS is free software; you can redistribute it and/or modify it under
  29 ;    the terms of the GNU General Public License (version 2) as published by the
  30 ;    Free Software Foundation AND MODIFIED BY the FreeRTOS exception.
  31 ;    >>>NOTE<<< The modification to the GPL is included to allow you to
  32 ;    distribute a combined work that includes FreeRTOS without being obliged to
  33 ;    provide the source code for proprietary components outside of the FreeRTOS
  34 ;    kernel.  FreeRTOS is distributed in the hope that it will be useful, but
  35 ;    WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
  36 ;    or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License for
  37 ;    more details. You should have received a copy of the GNU General Public
  38 ;    License and the FreeRTOS license exception along with FreeRTOS; if not it
  39 ;    can be viewed here: http://www.freertos.org/a00114.html and also obtained
  40 ;    by writing to Richard Barry, contact details for whom are available on the
  41 ;    FreeRTOS WEB site.
  42 ;
  43 ;    1 tab == 4 spaces!
  44 ;
  45 ;    http://www.FreeRTOS.org - Documentation, latest information, license and
  46 ;    contact details.
  47 ;
  48 ;    http://www.SafeRTOS.com - A version that is certified for use in safety
  49 ;    critical systems.
  50 ;
  51 ;    http://www.OpenRTOS.com - Commercial support, development, porting,
  52 ;    licensing and training services.
  53 ;*/
  54
  55         EXTERN  vTaskSwitchContext
  56         EXTERN  ulCriticalNesting
  57         EXTERN  pxCurrentTCB
  58         EXTERN  ulPortTaskHasFPUContext
  59         EXTERN  ulAsmAPIPriorityMask
  60
  61 portSAVE_CONTEXT macro
  62
  63         ; Save the LR and SPSR onto the system mode stack before switching to
  64         ; system mode to save the remaining system mode registers
  65         SRSDB   sp!, #SYS_MODE
  66         CPS             #SYS_MODE
  67         PUSH    {R0-R12, R14}
  68
  69         ; Push the critical nesting count
  70         LDR             R2, =ulCriticalNesting
  71         LDR             R1, [R2]
  72         PUSH    {R1}
  73
  74         ; Does the task have a floating point context that needs saving?  If
  75         ; ulPortTaskHasFPUContext is 0 then no.
  76         LDR             R2, =ulPortTaskHasFPUContext
  77         LDR             R3, [R2]
  78         CMP             R3, #0
  79
  80         ; Save the floating point context, if any
  81         FMRXNE  R1,  FPSCR
  82         VPUSHNE {D0-D15}
  83         VPUSHNE {D16-D31}
  84         PUSHNE  {R1}
  85
  86         ; Save ulPortTaskHasFPUContext itself
  87         PUSH    {R3}
  88
  89         ; Save the stack pointer in the TCB
  90         LDR             R0, =pxCurrentTCB
  91         LDR             R1, [R0]
  92         STR             SP, [R1]
  93
  94         endm
  95
  96 ; /**********************************************************************/
  97
  98 portRESTORE_CONTEXT macro
  99
 100         ; Set the SP to point to the stack of the task being restored.
 101         LDR             R0, =pxCurrentTCB
 102         LDR             R1, [R0]
 103         LDR             SP, [R1]
 104
 105         ; Is there a floating point context to restore?  If the restored
 106         ; ulPortTaskHasFPUContext is zero then no.
 107         LDR             R0, =ulPortTaskHasFPUContext
 108         POP             {R1}
 109         STR             R1, [R0]
 110         CMP             R1, #0
 111
 112         ; Restore the floating point context, if any
 113         POPNE   {R0}
 114         VPOPNE  {D16-D31}
 115         VPOPNE  {D0-D15}
 116         VMSRNE  FPSCR, R0
 117
 118         ; Restore the critical section nesting depth
 119         LDR             R0, =ulCriticalNesting
 120         POP             {R1}
 121         STR             R1, [R0]
 122
 123         ; Ensure the priority mask is correct for the critical nesting depth
 124         LDR             R2, =portICCPMR_PRIORITY_MASK_REGISTER_ADDRESS
 125         CMP             R1, #0
 126         MOVEQ   R4, #255
 127         LDRNE   R4, =( configMAX_API_CALL_INTERRUPT_PRIORITY << portPRIORITY_SHIFT )
 128         STR             R4, [r2]
 129
 130         ; Restore all system mode registers other than the SP (which is already
 131         ; being used)
 132         POP             {R0-R12, R14}
 133
 134         ; Return to the task code, loading CPSR on the way.
 135         RFEIA   sp!
 136
 137         endm
 138
 139
 140
 141
 142