begriffs open source - cmsis-freertos/blob - Utilities/gen_pack.bat

   1 :: Batch file for generating CMSIS-FreeRTOS pack
   2 :: This batch file uses:
   3 ::    7-Zip for packaging
   4 ::    Doxygen version 1.8.2 and Mscgen version 0.20 for generating html documentation.
   5 :: The generated pack and pdsc file are placed in folder %RELEASE_PATH% (../Local_Release)
   6 @ECHO off
   7
   8 SETLOCAL
   9
  10 :: Tool path for zipping tool 7-Zip
  11 SET ZIPPATH=C:\Program Files\7-Zip
  12
  13 :: Tool path for doxygen
  14 SET DOXYGENPATH=C:\Program Files\doxygen\bin
  15
  16 :: Tool path for mscgen utility
  17 SET MSCGENPATH=C:\Program Files (x86)\Mscgen
  18
  19 :: These settings should be passed on to subprocesses as well
  20 SET PATH=%ZIPPATH%;%DOXYGENPATH%;%MSCGENPATH%;%PATH%
  21
  22 :: Pack Path (where generated pack is stored)
  23 SET RELEASE_PATH=..\Local_Release
  24
  25 :: !!!!!!!!!!!!!!!!!
  26 :: DO NOT EDIT BELOW
  27 :: !!!!!!!!!!!!!!!!!
  28
  29 :: Remove previous build
  30 IF EXIST %RELEASE_PATH% (
  31   ECHO removing %RELEASE_PATH%
  32   RMDIR /Q /S  %RELEASE_PATH%
  33 )
  34
  35 :: Generate Documentation
  36 PUSHD ..\DoxyGen
  37 CALL genDoc.bat
  38 POPD
  39
  40
  41 :: Create build output directory
  42 MKDIR %RELEASE_PATH%
  43
  44 :: Copy PDSC file
  45 COPY .\..\ARM.CMSIS-FreeRTOS.pdsc %RELEASE_PATH%\ARM.CMSIS-FreeRTOS.pdsc
  46
  47 :: Copy LICENSE file
  48 XCOPY /Q /S /Y .\..\License\*.* %RELEASE_PATH%\License\*.*
  49 :: Copy CMSIS folder
  50 XCOPY /Q /S /Y .\..\CMSIS\*.* %RELEASE_PATH%\CMSIS\*.*
  51
  52 :: Copy Config folder
  53 XCOPY /Q /S /Y .\..\Config\*.* %RELEASE_PATH%\Config\*.*
  54
  55 :: Copy Source folder
  56 XCOPY /Q /S /Y .\..\Source\*.* %RELEASE_PATH%\Source\*.*
  57
  58 :: Remove generated doxygen files
  59 RMDIR /S /Q ..\CMSIS\Documentation
  60
  61 :: Checking
  62 :: Silencing warnings that are irrelevant in the context (M324, M382, M363)
  63 Win32\PackChk.exe %RELEASE_PATH%\ARM.CMSIS-FreeRTOS.pdsc -n %RELEASE_PATH%\PackName.txt -x M324 -x M382 -x M363 -x M362
  64
  65 :: --Check if PackChk.exe has completed successfully
  66 IF %errorlevel% neq 0 GOTO ErrPackChk
  67
  68 :: Packing
  69 PUSHD %RELEASE_PATH%
  70
  71 :: -- Pipe Pack's Name into Variable
  72 SET /P PackName=<PackName.txt
  73 DEL /Q PackName.txt
  74
  75 :: Pack files
  76 ECHO Creating pack file ...
  77 7z.exe a %PackName% -tzip > zip.log
  78 ECHO Packaging complete
  79 POPD
  80 GOTO End
  81
  82 :ErrPackChk
  83 ECHO PackChk.exe has encountered an error!
  84 EXIT /b
  85
  86 :End
  87 ECHO Removing temporary files and folders
  88 PUSHD %RELEASE_PATH%
  89 FOR %%A IN (CMSIS Config Demo License Source) DO IF EXIST %%A (RMDIR /S /Q %%A)
  90 DEL zip.log
  91 POPD
  92
  93 ECHO gen_pack.bat completed successfully