begriffs open source - freertos/blob - portable/IAR/78K0R/ISR_Support.h

   1 ;/*
   2 ; * FreeRTOS SMP Kernel V202110.00
   3 ; * Copyright (C) 2020 Amazon.com, Inc. or its affiliates.  All Rights Reserved.
   4 ; *
   5 ; * Permission is hereby granted, free of charge, to any person obtaining a copy of
   6 ; * this software and associated documentation files (the "Software"), to deal in
   7 ; * the Software without restriction, including without limitation the rights to
   8 ; * use, copy, modify, merge, publish, distribute, sublicense, and/or sell copies of
   9 ; * the Software, and to permit persons to whom the Software is furnished to do so,
  10 ; * subject to the following conditions:
  11 ; *
  12 ; * The above copyright notice and this permission notice shall be included in all
  13 ; * copies or substantial portions of the Software.
  14 ; *
  15 ; * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  16 ; * IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY, FITNESS
  17 ; * FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE AUTHORS OR
  18 ; * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER
  19 ; * IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN
  20 ; * CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
  21 ; *
  22 ; * https://www.FreeRTOS.org
  23 ; * https://github.com/FreeRTOS
  24 ; *
  25 ; * 1 tab == 4 spaces!
  26 ; */
  27
  28 #include "FreeRTOSConfig.h"
  29
  30 ; Variables used by scheduler
  31 ;------------------------------------------------------------------------------
  32         EXTERN    pxCurrentTCB
  33         EXTERN    usCriticalNesting
  34
  35 ;------------------------------------------------------------------------------
  36 ;   portSAVE_CONTEXT MACRO
  37 ;   Saves the context of the general purpose registers, CS and ES (only in far
  38 ;       memory mode) registers the usCriticalNesting Value and the Stack Pointer
  39 ;   of the active Task onto the task stack
  40 ;------------------------------------------------------------------------------
  41 portSAVE_CONTEXT MACRO
  42
  43         PUSH      AX                    ; Save AX Register to stack.
  44         PUSH      HL
  45         MOV       A, CS                 ; Save CS register.
  46         XCH       A, X
  47         MOV       A, ES                 ; Save ES register.
  48         PUSH      AX
  49         PUSH      DE                    ; Save the remaining general purpose registers.
  50         PUSH      BC
  51         MOVW      AX, usCriticalNesting ; Save the usCriticalNesting value.
  52         PUSH      AX
  53         MOVW      AX, pxCurrentTCB          ; Save the Stack pointer.
  54         MOVW      HL, AX
  55         MOVW      AX, SP
  56         MOVW      [HL], AX
  57         ENDM
  58 ;------------------------------------------------------------------------------
  59
  60 ;------------------------------------------------------------------------------
  61 ;   portRESTORE_CONTEXT MACRO
  62 ;   Restores the task Stack Pointer then use this to restore usCriticalNesting,
  63 ;   general purpose registers and the CS and ES (only in far memory mode)
  64 ;   of the selected task from the task stack
  65 ;------------------------------------------------------------------------------
  66 portRESTORE_CONTEXT MACRO
  67         MOVW      AX, pxCurrentTCB          ; Restore the Stack pointer.
  68         MOVW      HL, AX
  69         MOVW      AX, [HL]
  70         MOVW      SP, AX
  71         POP           AX                        ; Restore usCriticalNesting value.
  72         MOVW      usCriticalNesting, AX
  73         POP           BC                    ; Restore the necessary general purpose registers.
  74         POP           DE
  75         POP       AX                    ; Restore the ES register.
  76         MOV       ES, A
  77         XCH       A, X                  ; Restore the CS register.
  78         MOV       CS, A
  79         POP       HL                    ; Restore general purpose register HL.
  80         POP       AX                    ; Restore AX.
  81         ENDM
  82 ;------------------------------------------------------------------------------