begriffs open source - freertos/blob - portable/IAR/AtmelSAM9XE/ISR_Support.h

   1 ;/*
   2 ; * FreeRTOS Kernel <DEVELOPMENT BRANCH>
   3 ; * Copyright (C) 2021 Amazon.com, Inc. or its affiliates.  All Rights Reserved.
   4 ; *
   5 ; * SPDX-License-Identifier: MIT
   6 ; *
   7 ; * Permission is hereby granted, free of charge, to any person obtaining a copy of
   8 ; * this software and associated documentation files (the "Software"), to deal in
   9 ; * the Software without restriction, including without limitation the rights to
  10 ; * use, copy, modify, merge, publish, distribute, sublicense, and/or sell copies of
  11 ; * the Software, and to permit persons to whom the Software is furnished to do so,
  12 ; * subject to the following conditions:
  13 ; *
  14 ; * The above copyright notice and this permission notice shall be included in all
  15 ; * copies or substantial portions of the Software.
  16 ; *
  17 ; * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  18 ; * IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY, FITNESS
  19 ; * FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE AUTHORS OR
  20 ; * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER
  21 ; * IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN
  22 ; * CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
  23 ; *
  24 ; * https://www.FreeRTOS.org
  25 ; * https://github.com/FreeRTOS
  26 ; *
  27 ; */
  28         EXTERN pxCurrentTCB
  29         EXTERN ulCriticalNesting
  30
  31 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  32 ; Context save and restore macro definitions
  33 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  34
  35 portSAVE_CONTEXT MACRO
  36
  37         ; Push R0 as we are going to use the register.
  38         STMDB   SP!, {R0}
  39
  40         ; Set R0 to point to the task stack pointer.
  41         STMDB   SP, {SP}^
  42         NOP
  43         SUB             SP, SP, #4
  44         LDMIA   SP!, {R0}
  45
  46         ; Push the return address onto the stack.
  47         STMDB   R0!, {LR}
  48
  49         ; Now we have saved LR we can use it instead of R0.
  50         MOV             LR, R0
  51
  52         ; Pop R0 so we can save it onto the system mode stack.
  53         LDMIA   SP!, {R0}
  54
  55         ; Push all the system mode registers onto the task stack.
  56         STMDB   LR, {R0-LR}^
  57         NOP
  58         SUB             LR, LR, #60
  59
  60         ; Push the SPSR onto the task stack.
  61         MRS             R0, SPSR
  62         STMDB   LR!, {R0}
  63
  64         LDR             R0, =ulCriticalNesting
  65         LDR             R0, [R0]
  66         STMDB   LR!, {R0}
  67
  68         ; Store the new top of stack for the task.
  69         LDR             R1, =pxCurrentTCB
  70         LDR             R0, [R1]
  71         STR             LR, [R0]
  72
  73         ENDM
  74
  75
  76 portRESTORE_CONTEXT MACRO
  77
  78         ; Set the LR to the task stack.
  79         LDR             R1, =pxCurrentTCB
  80         LDR             R0, [R1]
  81         LDR             LR, [R0]
  82
  83         ; The critical nesting depth is the first item on the stack.
  84         ; Load it into the ulCriticalNesting variable.
  85         LDR             R0, =ulCriticalNesting
  86         LDMFD   LR!, {R1}
  87         STR             R1, [R0]
  88
  89         ; Get the SPSR from the stack.
  90         LDMFD   LR!, {R0}
  91         MSR             SPSR_cxsf, R0
  92
  93         ; Restore all system mode registers for the task.
  94         LDMFD   LR, {R0-R14}^
  95         NOP
  96
  97         ; Restore the return address.
  98         LDR             LR, [LR, #+60]
  99
 100         ; And return - correcting the offset in the LR to obtain the
 101         ; correct address.
 102         SUBS    PC, LR, #4
 103
 104         ENDM
 105