begriffs open source - freertos/blob - portable/GCC/RL78/isr_support.h

   1 /*
   2  * FreeRTOS Kernel <DEVELOPMENT BRANCH>
   3  * Copyright (C) 2021 Amazon.com, Inc. or its affiliates. All Rights Reserved.
   4  *
   5  * SPDX-License-Identifier: MIT
   6  *
   7  * Permission is hereby granted, free of charge, to any person obtaining a copy of
   8  * this software and associated documentation files (the "Software"), to deal in
   9  * the Software without restriction, including without limitation the rights to
  10  * use, copy, modify, merge, publish, distribute, sublicense, and/or sell copies of
  11  * the Software, and to permit persons to whom the Software is furnished to do so,
  12  * subject to the following conditions:
  13  *
  14  * The above copyright notice and this permission notice shall be included in all
  15  * copies or substantial portions of the Software.
  16  *
  17  * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  18  * IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY, FITNESS
  19  * FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE AUTHORS OR
  20  * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER
  21  * IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN
  22  * CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
  23  *
  24  * https://www.FreeRTOS.org
  25  * https://github.com/FreeRTOS
  26  *
  27  */
  28
  29 /* Variables used by scheduler */
  30 .extern _pxCurrentTCB
  31    .extern _usCriticalNesting
  32
  33 /*
  34  * portSAVE_CONTEXT MACRO
  35  * Saves the context of the general purpose registers, CS and ES (only in far
  36  * memory mode) registers the usCriticalNesting Value and the Stack Pointer
  37  * of the active Task onto the task stack
  38  */
  39    .macro portSAVE_CONTEXT
  40
  41 SEL RB0
  42
  43 /* Save AX Register to stack. */
  44 PUSH AX
  45 PUSH HL
  46 /* Save CS register. */
  47 MOV A, CS
  48 XCH A, X
  49 /* Save ES register. */
  50 MOV A, ES
  51 PUSH AX
  52 /* Save the remaining general purpose registers from bank 0. */
  53 PUSH DE
  54 PUSH BC
  55 /* Save the other register banks - only necessary in the GCC port. */
  56 SEL RB1
  57 PUSH AX
  58 PUSH BC
  59 PUSH DE
  60 PUSH HL
  61 SEL RB2
  62 PUSH AX
  63 PUSH BC
  64 PUSH DE
  65 PUSH HL
  66 /* Registers in bank 3 are for ISR use only so don't need saving. */
  67 SEL RB0
  68 /* Save the usCriticalNesting value. */
  69 MOVW AX, !_usCriticalNesting
  70 PUSH AX
  71 /* Save the Stack pointer. */
  72 MOVW AX, !_pxCurrentTCB
  73 MOVW HL, AX
  74 MOVW AX, SP
  75 MOVW[ HL ], AX
  76 /* Switch stack pointers. */
  77 movw sp, # _stack /* Set stack pointer */
  78
  79    .endm
  80
  81
  82 /*
  83  * portRESTORE_CONTEXT MACRO
  84  * Restores the task Stack Pointer then use this to restore usCriticalNesting,
  85  * general purpose registers and the CS and ES (only in far memory mode)
  86  * of the selected task from the task stack
  87  */
  88    .macro portRESTORE_CONTEXT MACRO
  89 SEL RB0
  90 /* Restore the Stack pointer. */
  91 MOVW AX, !_pxCurrentTCB
  92 MOVW HL, AX
  93 MOVW AX, [ HL ]
  94 MOVW SP, AX
  95 /* Restore usCriticalNesting value. */
  96 POP AX
  97 MOVW    !_usCriticalNesting, AX
  98
  99 /* Restore the alternative register banks - only necessary in the GCC
 100  * port.  Register bank 3 is dedicated for interrupts use so is not saved or
 101  * restored. */
 102 SEL RB2
 103 POP HL
 104 POP DE
 105 POP BC
 106 POP AX
 107 SEL RB1
 108 POP HL
 109 POP DE
 110 POP BC
 111 POP AX
 112 SEL RB0
 113 /* Restore the necessary general purpose registers. */
 114 POP BC
 115 POP DE
 116 /* Restore the ES register. */
 117 POP AX
 118 MOV ES, A
 119 /* Restore the CS register. */
 120 XCH A, X
 121 MOV CS, A
 122 /* Restore general purpose register HL. */
 123 POP HL
 124 /* Restore AX. */
 125 POP AX
 126
 127    .endm