begriffs open source - freertos/blob - FreeRTOS/Source/portable/MPLAB/PIC32MX/ISR_Support.h

   1 /*\r
   2     FreeRTOS V7.5.3 - Copyright (C) 2013 Real Time Engineers Ltd. \r
   3     All rights reserved\r
   4 \r
   5     VISIT http://www.FreeRTOS.org TO ENSURE YOU ARE USING THE LATEST VERSION.\r
   6 \r
   7     ***************************************************************************\r
   8      *                                                                       *\r
   9      *    FreeRTOS provides completely free yet professionally developed,    *\r
  10      *    robust, strictly quality controlled, supported, and cross          *\r
  11      *    platform software that has become a de facto standard.             *\r
  12      *                                                                       *\r
  13      *    Help yourself get started quickly and support the FreeRTOS         *\r
  14      *    project by purchasing a FreeRTOS tutorial book, reference          *\r
  15      *    manual, or both from: http://www.FreeRTOS.org/Documentation        *\r
  16      *                                                                       *\r
  17      *    Thank you!                                                         *\r
  18      *                                                                       *\r
  19     ***************************************************************************\r
  20 \r
  21     This file is part of the FreeRTOS distribution.\r
  22 \r
  23     FreeRTOS is free software; you can redistribute it and/or modify it under\r
  24     the terms of the GNU General Public License (version 2) as published by the\r
  25     Free Software Foundation >>!AND MODIFIED BY!<< the FreeRTOS exception.\r
  26 \r
  27     >>! NOTE: The modification to the GPL is included to allow you to distribute\r
  28     >>! a combined work that includes FreeRTOS without being obliged to provide\r
  29     >>! the source code for proprietary components outside of the FreeRTOS\r
  30     >>! kernel.\r
  31 \r
  32     FreeRTOS is distributed in the hope that it will be useful, but WITHOUT ANY\r
  33     WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS\r
  34     FOR A PARTICULAR PURPOSE.  Full license text is available from the following\r
  35     link: http://www.freertos.org/a00114.html\r
  36 \r
  37     1 tab == 4 spaces!\r
  38 \r
  39     ***************************************************************************\r
  40      *                                                                       *\r
  41      *    Having a problem?  Start by reading the FAQ "My application does   *\r
  42      *    not run, what could be wrong?"                                     *\r
  43      *                                                                       *\r
  44      *    http://www.FreeRTOS.org/FAQHelp.html                               *\r
  45      *                                                                       *\r
  46     ***************************************************************************\r
  47 \r
  48     http://www.FreeRTOS.org - Documentation, books, training, latest versions,\r
  49     license and Real Time Engineers Ltd. contact details.\r
  50 \r
  51     http://www.FreeRTOS.org/plus - A selection of FreeRTOS ecosystem products,\r
  52     including FreeRTOS+Trace - an indispensable productivity tool, a DOS\r
  53     compatible FAT file system, and our tiny thread aware UDP/IP stack.\r
  54 \r
  55     http://www.OpenRTOS.com - Real Time Engineers ltd license FreeRTOS to High\r
  56     Integrity Systems to sell under the OpenRTOS brand.  Low cost OpenRTOS\r
  57     licenses offer ticketed support, indemnification and middleware.\r
  58 \r
  59     http://www.SafeRTOS.com - High Integrity Systems also provide a safety\r
  60     engineered and independently SIL3 certified version for use in safety and\r
  61     mission critical applications that require provable dependability.\r
  62 \r
  63     1 tab == 4 spaces!\r
  64 */\r
  65 \r
  66 #include "FreeRTOSConfig.h"\r
  67 \r
  68 #define portCONTEXT_SIZE 132\r
  69 #define portEPC_STACK_LOCATION  124\r
  70 #define portSTATUS_STACK_LOCATION 128\r
  71 \r
  72 /******************************************************************/    \r
  73 .macro  portSAVE_CONTEXT\r
  74 \r
  75         /* Make room for the context. First save the current status so we can \r
  76         manipulate it, and the cause and EPC registers so we capture their \r
  77         original values in case of interrupt nesting. */\r
  78         mfc0            k0, _CP0_CAUSE\r
  79         addiu           sp,     sp, -portCONTEXT_SIZE\r
  80         mfc0            k1, _CP0_STATUS\r
  81 \r
  82         /* Also save s6 and s5 so we can use them during this interrupt.  Any\r
  83         nesting interrupts should maintain the values of these registers\r
  84         across the ISR. */\r
  85         sw                      s6, 44(sp)\r
  86         sw                      s5, 40(sp)\r
  87         sw                      k1, portSTATUS_STACK_LOCATION(sp)\r
  88 \r
  89         /* Enable interrupts above the current priority. */\r
  90         srl                     k0, k0, 0xa\r
  91         ins             k1, k0, 10, 6\r
  92         ins                     k1, zero, 1, 4\r
  93 \r
  94         /* s5 is used as the frame pointer. */\r
  95         add                     s5, zero, sp\r
  96 \r
  97         /* Check the nesting count value. */\r
  98         la                      k0, uxInterruptNesting\r
  99         lw                      s6, (k0)\r
 100 \r
 101         /* If the nesting count is 0 then swap to the the system stack, otherwise\r
 102         the system stack is already being used. */\r
 103         bne                     s6, zero, .+20\r
 104         nop\r
 105 \r
 106         /* Swap to the system stack. */\r
 107         la                      sp, xISRStackTop\r
 108         lw                      sp, (sp)\r
 109 \r
 110         /* Increment and save the nesting count. */\r
 111         addiu           s6, s6, 1\r
 112         sw                      s6, 0(k0)\r
 113 \r
 114         /* s6 holds the EPC value, this is saved after interrupts are re-enabled. */\r
 115         mfc0            s6, _CP0_EPC\r
 116 \r
 117         /* Re-enable interrupts. */\r
 118         mtc0            k1, _CP0_STATUS\r
 119 \r
 120         /* Save the context into the space just created.  s6 is saved again\r
 121         here as it now contains the EPC value.  No other s registers need be\r
 122         saved. */\r
 123         sw                      ra,     120(s5)\r
 124         sw                      s8, 116(s5)\r
 125         sw                      t9, 112(s5)\r
 126         sw                      t8,     108(s5)\r
 127         sw                      t7,     104(s5)\r
 128         sw                      t6, 100(s5)\r
 129         sw                      t5, 96(s5)\r
 130         sw                      t4, 92(s5)\r
 131         sw                      t3, 88(s5)\r
 132         sw                      t2, 84(s5)\r
 133         sw                      t1, 80(s5)\r
 134         sw                      t0, 76(s5)\r
 135         sw                      a3, 72(s5)\r
 136         sw                      a2, 68(s5)\r
 137         sw                      a1, 64(s5)\r
 138         sw                      a0, 60(s5)\r
 139         sw                      v1, 56(s5)\r
 140         sw                      v0, 52(s5)\r
 141         sw                      s6, portEPC_STACK_LOCATION(s5)\r
 142         sw                      $1, 16(s5)\r
 143 \r
 144         /* s6 is used as a scratch register. */\r
 145         mfhi            s6\r
 146         sw                      s6, 12(s5)\r
 147         mflo            s6\r
 148         sw                      s6, 8(s5)\r
 149 \r
 150         /* Update the task stack pointer value if nesting is zero. */\r
 151         la                      s6, uxInterruptNesting\r
 152         lw                      s6, (s6)\r
 153         addiu           s6, s6, -1\r
 154         bne                     s6, zero, .+20\r
 155         nop\r
 156 \r
 157         /* Save the stack pointer. */\r
 158         la                      s6, uxSavedTaskStackPointer\r
 159         sw                      s5, (s6)\r
 160 \r
 161         .endm\r
 162         \r
 163 /******************************************************************/    \r
 164 .macro  portRESTORE_CONTEXT\r
 165 \r
 166         /* Restore the stack pointer from the TCB.  This is only done if the\r
 167         nesting count is 1. */\r
 168         la                      s6, uxInterruptNesting\r
 169         lw                      s6, (s6)\r
 170         addiu           s6, s6, -1\r
 171         bne                     s6, zero, .+20\r
 172         nop\r
 173         la                      s6, uxSavedTaskStackPointer\r
 174         lw                      s5, (s6)\r
 175         \r
 176         /* Restore the context. */\r
 177         lw                      s6, 8(s5)\r
 178         mtlo            s6\r
 179         lw                      s6, 12(s5)\r
 180         mthi            s6\r
 181         lw                      $1, 16(s5)\r
 182         /* s6 is loaded as it was used as a scratch register and therefore saved\r
 183         as part of the interrupt context. */\r
 184         lw                      s6, 44(s5)\r
 185         lw                      v0, 52(s5)\r
 186         lw                      v1, 56(s5)\r
 187         lw                      a0, 60(s5)\r
 188         lw                      a1, 64(s5)\r
 189         lw                      a2, 68(s5)\r
 190         lw                      a3, 72(s5)\r
 191         lw                      t0, 76(s5)\r
 192         lw                      t1, 80(s5)\r
 193         lw                      t2, 84(s5)\r
 194         lw                      t3, 88(s5)\r
 195         lw                      t4, 92(s5)\r
 196         lw                      t5, 96(s5)\r
 197         lw                      t6, 100(s5)\r
 198         lw                      t7, 104(s5)\r
 199         lw                      t8, 108(s5)\r
 200         lw                      t9, 112(s5)\r
 201         lw                      s8, 116(s5)\r
 202         lw                      ra, 120(s5)\r
 203 \r
 204         /* Protect access to the k registers, and others. */\r
 205         di\r
 206 \r
 207         /* Decrement the nesting count. */\r
 208         la                      k0, uxInterruptNesting\r
 209         lw                      k1, (k0)\r
 210         addiu           k1, k1, -1\r
 211         sw                      k1, 0(k0)\r
 212 \r
 213         lw                      k0, portSTATUS_STACK_LOCATION(s5)\r
 214         lw                      k1, portEPC_STACK_LOCATION(s5)\r
 215 \r
 216         /* Leave the stack how we found it.  First load sp from s5, then restore\r
 217         s5 from the stack. */\r
 218         add                     sp, zero, s5\r
 219         lw                      s5, 40(sp)\r
 220         addiu           sp,     sp,     portCONTEXT_SIZE\r
 221 \r
 222         mtc0            k0, _CP0_STATUS\r
 223         mtc0            k1, _CP0_EPC\r
 224         eret \r
 225         nop\r
 226 \r
 227         .endm\r
 228 \r